home *** CD-ROM | disk | FTP | other *** search
/ The Original Shareware 1.1 / The Original Shareware (WeMake CDs)(Volume 1.1)(CDs, Inc)(1993).iso / 36 / dv_guard.zip / DV-GUARD.ASM next >
Assembly Source File  |  1990-03-11  |  8KB  |  335 lines
  1.  page ,132
  2.  .model tiny
  3.  .code
  4. first:
  5. ;
  6. ; DV-GUARD is an enhanced version of the marvelously written original
  7. ;    WATCHCAT program created by Joseph R. Ahlgren.
  8. ;    With his permission, it has been revised to allow use in
  9. ;    the DESQview environment.  In addition, due to popular request,
  10. ;    the original "20 ring reboot" feature has been modified to
  11. ;    reboot the system on 8 rings.
  12. ;
  13. ; Many people have contributed to this revised program.  Quarterdeck
  14. ;    Office Systems (the developers of DESQview), were certainly 
  15. ;    instrumental in making this version a success.  In addition, the
  16. ;    dedication of programmer Anthony Petillo was an absolute
  17. ;    necessity to making this whole thing come about.
  18. ;
  19. ; For more information, please see DV-GUARD.DOC 
  20. ;   
  21. ; 
  22. ;
  23. ; DV-GUARD performs 5 critical functions for any RBBS system
  24. ;          running under DESQview:
  25. ;
  26. ;  1.  Reboots the system if no carrier is detected in 8 hours.
  27. ;      This catches RBBS or system failures.
  28. ;
  29. ;  2.  Reboots the system if carrier is lost during critical period.
  30. ;      This allows Doors to be used safely.
  31. ;
  32. ;  3.  Reboots the system if 8 rings without answering phone.
  33. ;      This allows system to be restarted by phone.
  34. ;
  35. ;  4.  Reboots system if "Hit any key to return to system" message appears.
  36. ;      This restarts system on an RBBS glitch.
  37. ;
  38. ;  5.  Drops carrier if L&R shift keys pressed simultaneously.
  39. ;      This allows users to be logged off without a nasty message.
  40. ;
  41. ;
  42. ; DV-GUARD loads the TSR and disables all functions
  43. ; DV-GUARD OFF disables all functions
  44. ; DV-GUARD ON enables 1,3,4,and 5
  45. ; DV-GUARD TIMER enables 2,4,and 5
  46. ;
  47. ;ComPort = 03f8h  ;{COM1}
  48. ;ComPort = 02f8h  ;{COM2}
  49. ;ComPort = 03e8h  ;{COM3}
  50. ;ComPort = 02e8h  ;{COM4}
  51. ;ScreenSegment = 0b800h  ;{Color}
  52. ;ScreenSegment = 0b000h  ;{Mono}
  53. ;
  54. ModemStatus = 0006h
  55. ModemControl = 0004h
  56. CarrierDetect = 0080h
  57. RingIndicator = 0040h
  58. tpm = 1092 ; {ticks per minute}
  59. RingTicks = 110; {6 seconds}
  60.  org 100h
  61. start:
  62.  jmp init
  63. RingTrigger dw 0
  64. RingTimer db 0
  65. Flag db 'F' and 0fh  ;  OFF ON TIME = F O I
  66. TimerInt dd ?
  67. Minutes dw 8*60  ;{minutes of no carrier to trigger reset}
  68. Seconds dw tpm
  69. MinReset dw 8*60
  70. WarmBoot dd 0f000fff0h
  71. ExitTimer db 0
  72. DropTrigger db 3  ;Drop DTR on L&R shift
  73. ExitMessage db 'Hit any key to return to system'
  74. ExitMessageEnd db 0
  75. ComPort dw 02f8h  ;{COM2}
  76. ScreenSegment dw 0b000h  ;{Mono}
  77. Ident db "jOeY"
  78. Ident2 db "50c4"
  79. timer:
  80.  assume ds:nothing,es:nothing,ss:nothing
  81.  cmp cs:[Flag],'F' and 0fh
  82.  jne SystemOn
  83.  jmp cs:[TimerInt]
  84. SystemOn:
  85.  push ax
  86.  push dx
  87.  push ds
  88. ;
  89. ;
  90. ;  4.  Reboots the system if "Hit any key to return to system" message appears.
  91. ;      This restarts the system on an RBBS glitch.
  92. ;
  93.  dec cs:[ExitTimer]
  94.  jnz NoExitLoop
  95.  push cx
  96.  push si
  97.  push di
  98.  mov ax,cs:[ScreenSegment]
  99.  mov ds,ax
  100.  mov cx,25
  101.  xor si,si
  102. SSLoop1:
  103.  push cx
  104.  push si
  105.  mov cx,ExitMessageEnd-ExitMessage
  106.  mov di,offset ExitMessage
  107. SSLoop2:
  108.  lodsw
  109.  cmp al,cs:[di]
  110.  jne SSLoop2x
  111.  inc di
  112.  loop SSLoop2
  113.  jmp short NoCarrier
  114. SSLoop2x:
  115.  pop si
  116.  pop cx
  117.  add si,160
  118.  loop SSLoop1
  119.  pop di
  120.  pop si
  121.  pop cx
  122. NoExitLoop:
  123. ;
  124. ;
  125. ;  5.  Drops carrier if L&R shift keys pressed simultaneously.
  126. ;      This allows users to be logged off without a nasty message.
  127. ;
  128.  xor ax,ax
  129.  mov ds,ax
  130.  assume ds:Lowmem
  131.  mov al,[ShiftStatus]
  132.  and al,0fh
  133.  cmp al,cs:[DropTrigger]
  134.  jne NoShift
  135.  mov dx,cs:[ComPort]
  136.  add dx,ModemControl
  137.  in al,dx
  138.  and al,0feh
  139.  out dx,al       ;drop DTR
  140. NoShift:
  141. ;
  142. ;
  143. ;  3.  Reboots the system if 8 rings without answering phone.
  144. ;      This allows system to be restarted by phone.
  145. ;
  146.  mov dx,[ComPort]
  147.  add dx,ModemStatus
  148.  in al,dx
  149.  test al,RingIndicator
  150.  jz NotRinging
  151.  or cs:[RingTrigger],1
  152. NotRinging:
  153.  dec cs:[RingTimer]
  154.  jnz NoRingTime
  155.  mov cs:[RingTimer],RingTicks
  156.  mov ax,cs:[RingTrigger]
  157.  cmp ax,0ffffh
  158.  je NoCarrier
  159.  shl ax,1
  160.  mov cs:[RingTrigger],ax
  161. ;
  162. ;
  163. ;  2.  Reboots the system if carrier lost during critical period.
  164. ;      This allows Doors to be used safely.
  165. ;
  166. NoRingTime:
  167.  cmp cs:[Flag],'I' and 0fh
  168.  jb NoMonitor
  169.  je TimeCheck
  170.  in al,dx
  171.  and al,CarrierDetect
  172.  jz NoCarrier
  173. NoMonitor:
  174.  pop ds
  175.  pop dx
  176.  pop ax
  177.  jmp cs:[TimerInt]
  178. NoCarrier:
  179.   cli                           ; disable interrupts
  180.   mov ax,0                      ; clear ax
  181.   mov ds,ax                     ; clear data seg reg
  182.   mov bx,0472h                  ; store 1234 at address 472
  183.   mov word ptr [bx],01234h
  184.   mov ss,ax                     ; clear stack seg reg
  185.   mov sp,0400h                  ; set stack ptr to 400
  186.   jmp cs:[warmboot]             ; goto to warmboot area
  187. ;
  188. ;
  189. ;  1.  Reboots the system if no carrier in specified period of time.
  190. ;      This catches RBBS or system failures.
  191. ;
  192. TimeCheck:
  193.  test al,CarrierDetect
  194.  jnz ResetTime
  195.  dec cs:[Seconds]
  196.  jnz NoMonitor
  197.  mov cs:[Seconds],tpm
  198.  dec cs:[Minutes]
  199.  jz NoCarrier
  200.  jmp short NoMonitor
  201. ResetTime:
  202.  mov ax,cs:[MinReset]
  203.  mov cs:[Minutes],ax
  204.  jmp short NoMonitor
  205. ;
  206. ;
  207. ;
  208. ;
  209.  assume ds:@code,es:@code,ss:@code
  210. init:
  211.  mov dx,offset SignOnMessage
  212.  mov ax,0900h
  213.  int 21h     ;print load message
  214.  mov ax,[word ptr Ident2]
  215.  xor [word ptr Ident],ax
  216.  mov ax,[word ptr Ident2+2]
  217.  xor [word ptr Ident+2],ax
  218.  xor dx,dx
  219.  mov es,dx
  220.  mov si,offset Ident
  221.  mov cx,cs
  222.  mov ax,[si]
  223. findloop:
  224.  cmp ax,es:[si]
  225.  jz found
  226. NotQuite:
  227.  inc dx
  228.  mov es,dx
  229.  loop findloop
  230. LoadDVGUARD:
  231.  xor bx,bx
  232.  mov es,bx
  233.  mov bl,ds:[82h]
  234.  cmp bl,'0'
  235.  jle NoCom
  236.  cmp bl,'4'
  237.  jle ComSpec
  238. NoCom:
  239.  mov bl,'1'
  240. ComSpec:
  241.  mov [ComPortNumber],bl
  242.  add bx,bx
  243.  mov ax,es:[bx+400h-31h-31h]
  244.  mov [ComPort],ax
  245.  cmp byte ptr ds:[83h],'C'
  246.  jnz NotColor
  247.  mov [ScreenSegment],0b800h
  248.  mov [ScreenSegNum],'8'
  249. NotColor:
  250.  mov ax,3508h
  251.  int 21h     ;get timer interrupt
  252.  mov [word ptr TimerInt],bx
  253.  mov [word ptr TimerInt+2],es
  254.  mov dx,offset Timer
  255.  mov ax,2508h
  256.  int 21h     ;set timer interrupt
  257.  mov dx,offset message1
  258.  mov ax,0900h
  259.  int 21h     ;print load message
  260.  mov dx,(init-first+15)/16
  261.  mov ax,3101h
  262.  int 21h      ;TSR
  263. Found:
  264.  mov bx,[si+2]
  265.  cmp bx,es:[si+2]
  266.  jnz NotQuite
  267.  mov ax,es
  268.  mov bx,10h
  269.  mov di,offset message2x
  270.  mov cx,4
  271. loc:
  272.  mul bx
  273.  cmp dl,9
  274.  jbe locx
  275.  add dl,7
  276. locx:
  277.  add dl,'0'
  278.  mov [di],dl
  279.  inc di
  280.  loop loc
  281.  mov ax,es:[MinReset]
  282.  mov es:[Minutes],ax
  283.  mov al,ds:[83h]
  284.  and al,0fh
  285.  mov es:[Flag],al
  286.  mov dx,offset message2tim
  287.  cmp al,'I' and 0fh
  288.  jz done
  289.  mov dx,offset message2off
  290.  jb done
  291.  mov dx,offset message2on
  292. done:
  293.  push dx
  294.  mov dx,offset message2
  295.  mov ax,0900h
  296.  int 21h
  297.  pop dx
  298.  mov ax,0900h
  299.  int 21h
  300.  mov ax,4c00h
  301.  int 21h
  302. message1 db 0ah,0dh,'DV-GUARD Loaded, set to COM'
  303. ComPortNumber db '1 and Screen B'
  304. ScreenSegNum db '000',0ah,0dh,'$'
  305. message2 db 0ah,0dh,'DV-GUARD found at '
  306. message2x db '0000 and set to $'
  307. message2on db 'ON',0ah,0dh,'$'
  308. message2off db 'OFF',0ah,0dh,'$'
  309. message2tim db 'TIMER',0ah,0dh,'$'
  310. SignOnMessage db 0dh,0ah,'DV-GUARD: RBBS protection when running under DESQview'
  311.  db '   ',0dh,0ah
  312.  db ' DV-GUARD may be freely distributed and/or modified.  Enjoy!',0dh,0ah
  313.  db '   ',0dh,0ah
  314.  db ' Load with DV-GUARD ps, where p is the port number (1,2,3,4)',0dh,0ah
  315.  db '  and s is the screen type (Color or Mono), e.g., DV-GUARD 2C',0dh,0ah
  316.  db '  specifies COM2 and Color Screen',0ah,0dh
  317.  db '   ',0dh,0ah
  318.  db ' Subsequent calls are DV-GUARD ON, DV-GUARD OFF, and DV-GUARD TIMER',0dh,0ah
  319.  db '  OFF disables all functions',0dh,0ah
  320.  db '  ON reboots if carrier lost',0dh,0ah
  321.  db '  TIMER reboots if 8 rings without answering phone, if no carrier',0dh,0ah
  322.  db '   in 8 hours, or if "Hit any key to return to system" appears on screen',0dh,0ah
  323.  db '   Also, pressing both Left and Right Shift keys simultaneously will',0dh,0ah
  324.  db '   drop the line, logging off the current user.',0dh,0ah
  325.  db '$'
  326.  ends
  327. Lowmem segment at 0000h
  328.  org 417h
  329. ShiftStatus db ?
  330. Lowmem ends
  331.  end start
  332.  
  333.  
  334.  
  335.